CnPack Forum


 
Subject: Delphi面向对象学习随笔三:overload与override
bahamut8348
灌水司司长
Rank: 6Rank: 6


UID 4743
Digest Posts 14
Credits 337
Posts 79
点点分 337
Reading Access 10
Registered 2007-1-18
Status Offline
Post at 2008-6-20 17:46  Profile | Blog | P.M. 
Delphi面向对象学习随笔三:overload与override

Delphi面向对象学习随笔三:overload与override
    首先,我想单独说明一下overload,为什么呢?因为overload和对象化关联不大,所以,我感觉单独提出来说明比较好。
    我们都知道,在Pascal语法规则中,同一个UNIT里是不能存在两个同名的函数的,例如:

function func(): Boolean;
function func(const x: Char): Boolean;

这样是会出语法错误的,原因是因为标识符规则限制。但是问题出来了,如果我们需要几个功能相似但是参数不同的函数,那么根据标识符规则,我们就必须定义几个不同名,但是功能相同或相似的函数。
    如,假设我需要一个函数,要实现返回参数一减去参数二后的值,那么我们就将这样定义函数:

function SubInt(const Value1, Value2: Integer): Integer;
functino SubReal(const Value1, Value2: Real): Real;
function SubDouble(const Value1, Value2: Double): Double;

implementation

function SubInt(const Value1, Value2: Integer): Integer;
begin
  Result:= Value1 - Value2;
end;

functino SubReal(const Value1, Value2: Real): Real;
begin
  Result:= Value1 - Value2;
end;

function SubDouble(const Value1, Value2: Double): Double;
begin
  Result:= Value1 - Value2;
end;

我们可以看到,这三个函数除了参数名不同外,实现部分是一样的,这为程序的一致性带来了一定的麻烦。如果能定义一个同名函数来处理这几种不同情况的话,便有利于代码的重用,也有利于我们的记忆。这时我们就可以用overload来完成我们的需求了。

function Sub(const Value1, Value2: Integer): Integer; overload;
function Sub(const Value1, Value2: Real): Real; overload;
function Sub(const Value1, Value2: Double): Double; overload;

implementation

function Sub(const Value1, Value2: Integer): Integer;
begin
  Result:= Value1 - Value2;
end;

function Sub(const Value1, Value2: Real): Real;
begin
  Result:= Value1 - Value2;
end;

function Sub(const Value1, Value2: Double): Double;
begin
  Result:= Value1 - Value2;
end;

由此可见,名字相同而参数的数据类型或数量不同的函数,称之为overload函数。这是因为编译器在编译时不仅使用了函数名的信息,还使用了参数类型和数量的信息,通过组合这些信息可以确定分配地址时需要的唯一标识,通常我们叫他signature。例如:

Sub(1, 2);     // 调用的是 function Sub(const Value1, Value2: Integer): Integer;
Sub(1.0, 2.0); // 调用的是 function Sub(const Value1, Value2: Real): Real;

这里要说明一下,如果是同名函数,并且参数也相同,只是返回值不同的话,是不能实现overload的。

    对于overload的说明就到这里吧,下面我们来说override:
    前面我说过,在派生一个新类的时候,首先会继承父类中的所有可继承部分,那么就意味着,默认情况下,父类所有的非私有

部分的类成员或方法都已经包含在新类中。
    但是,如果我们要为类的一个方法添加新的代码而又不希望重写父类方法中原有功能的话,我们可以用override来实现方法的覆盖,并用inherited来继承(或者可以说调用)父类方法中的方法功能:

type
  TBaseClass = class(TObject)
    // 定义一个新的父类
  protected
    FMessage: string;
  public
    constructor Create();    // 构造方法
    procedure MessageBox(); virtual; // 显示字符串
  end;

  TChildClass = class(TBaseClass)
    // 定义一个TBaseClass的派生类
  public
    procedure MessageBox(); override; // 重载父类中的方法
  end;

implementation

constructor TBaseClass.Create;
begin
  inherited Create();   // 继承父类中的构造方法Create
  FMessage:= ClassName; // 初始化信息字符串为类名
end;

procedure TBaseClass.MessageBox;
begin
  ShowMessage(FMessage); // 显示字符串
end;

procedure TChildClass.MessageBox;
begin
  FMessage:= FMessage + FMessage;
  inherited MessageBox(); // 继承父类中原有MessageBox方法的原有功能
end;

好,我们可以编写一个简单的例子来调用一下:

var
  Child: TChildClass;
begin
  Child:= TChildClass.Create;
  Child.MessageBox();
  Child.Free;
end;

代码执行后,应该可以看到一个弹出“TChildClassTChildClass”字符串的对话框。
    以上代码只是简单的演示了类方法的继承,也许你会奇怪,为什么TBaseClass的构造方法Create没有用override关键字指定,却同样可以inherited来继承父类的该方法,其实不用override也是可以实现继承的(在这里如果你加上override反而会出语法错误,因为TObject类的Create是一个静态方法,而静态方法是不允许被override的),那么他们有什么不一样的呢?我们来看下面的例子:

var
  Child: TBaseClass;
begin
  Child:= TChildClass.Create;
  Child.MessageBox();
  Child.Free;
end;

执行这段测试代码和我们上面的代码是一样的效果的。然后我们再把TBaseClass类的方法MessageBox后的virtual关键字和子类中的override关键字去掉,再执行一次看看,应该是看到一个弹出“TChildClass”字符串的对话框。
    这是为什么呢?原因是因为virtual关键字,下面简单的说明一下virtual关键字:

  virtual和dynamic方法
    virtual关键字是指定方法为虚方法,Object Pascal中,默认情况下,所有方法都是静态的(当然和类方法不同),静态方法的特点是,在对象被创建的时候,编译器会分配所有调用静态方法时所指定的内存地址,也就是说,编译期即指定了调用的具体方法。
    而virtual和dynamic方法(虚方法和动态方法)则是在调用时动态分配的。他们的语义是相同的,唯一不同的是,他们的实现方法和调用方法,这涉及到DELPHI的编译机制。

    Delphi的编译器会自动维护用于添加虚方法的虚方法表(VMT)和用于添加动态方法的动态方法表(DMT)。
    虚方法表存放的是类及其基类声明的所有虚方法指针。每一个类都有并且只有一个虚方法表,当然每一个虚方法表都有一个入口。无论一个类是否有他自己定义的虚方法,只要他继承了祖先类的虚方法,他也就会有自己的虚方法表,并列举出他继承的所有虚方法。因为每一个类都有一个自己的虚方法表,Delphi就可以使用虚方法表来识别一个类,实际上,一个类引用就是指向类的虚方法表的指针。
    由于基类和派生类的虚方法表之间有过强的关联性,因此派生类继承了祖先类的虚方法,也就是说派生类的虚方法表的前面一部分必须与基类相同。而当基类和派生类不在同一个DLL或EXE中的时候,这个要求是很难满足的。基类一旦改变,派生类如果不重新编译,将导致错误。另外,如果类的继承很深,那么虚方法表将会因不断继承的虚方法而膨胀,导致效率低下。
    而动态方法则可以解决这个问题,每一个类的动态方法表中只维护部分的动态方法,也就是说动态方法表只列出了该类所声明的动态方法,他并不包括从祖先类那里继承来的动态方法。动态方法表使用了一种独特的编号和检索系统,当调用动态方法时,会在动态方法表中的Indexes数组中查找该方法的代号,一旦找到匹配该方法的代号,则方法指针会到相应的地址中调用方法。如果没有找到,则会搜索祖先类中的动态方法表。这样虽然解决了虚方法表膨胀的问题,但是产生了执行效率的问题。

    总的来说,虚方法侧重于提高速度,动态方法侧重于节省内存,如果某方法其后代类基本都需要override的,那么推荐使用virtual,如果某方法不经常或者几乎不在后代类中被override的,则推荐使用dynamic。

  abstract方法
    abstract方法就是我们常说的抽象方法,该方法只能有声明而不能有实现部分,一般只是提供给派生类override使用的,所以一般abstract关键字和virtual是一起出现的。而一般含有抽象方法的类一般我们叫他虚类。

  类方法
    类方法和C中的static方法有点相似,Object Pascal中的类方法是不需要实例化对象就可以调用的方法。由于他不需要为对象分配内存空间就可以调用他,那么也就意味着在类方法中不能引用类中的其他数据成员。
    类方法的声名如下:

type
  TNewClass = class(TObject)
  public
    class procedure AClassFunciton(...): ...;
  end;

鸣谢刘啸,没有刘啸的查错,文章将会难看很多,哈哈^_^
    待续……

[ 本帖最后由 bahamut8348 于 2008-6-20 17:49 编辑 ]




做人要厚道,看帖要回贴
Top
shenloqi
灌水处处长
Rank: 4



UID 34
Digest Posts 1
Credits 287
Posts 179
点点分 287
Reading Access 10
Registered 2003-3-15
Status Offline
Post at 2008-6-23 12:05  Profile | P.M. 
巴哈,说到overload可以顺带说一下缺省参数。

virtual其实最主要的影响是会增加编译出来的程序的大小,尤其是继承层次比较深的情况下。而dyanmic一般会比virtual慢一些,除了巴哈说的情况,如果调用不频繁,或者不成为瓶颈,以及位于继承层次比较基础的一些类可以使用dyanmic。
Top
zjy
管理员
Rank: 9Rank: 9Rank: 9



UID 2
Digest Posts 6
Credits 2385
Posts 1543
点点分 2385
Reading Access 102
Registered 2002-12-16
Location China
Status Offline
Post at 2008-6-23 18:50  Profile | Site | Blog | P.M. 
从面向对象的角度来看,overload与override都是面向对象的三特征“继承,封装,多态”中“多态”的具体实现。

多态性可以理解为同一个操作作用于不同的对象,将产生不同的行为。而多态性在语言中有两种实现方式:编译期的多态性和运行期的多态性。

overload对应编译期的多态性:相同的函数名,通过不同的参数数量和类型,可以实现不同的行为。而这种多态行为是由编译器来完成的,编译之后就不再变化。

override对应运行期的多态性:通过在子类中重载父类声明为virtual或dynamic的方法来实现运行期的动态多态性。




Zhou JingYu
CnPack Administrator
http://www.cnpack.org/
Top
wsc188
新警察
Rank: 1



UID 39119
Digest Posts 0
Credits 28
Posts 11
点点分 28
Reading Access 10
Registered 2008-3-22
Status Offline
Post at 2009-12-16 11:54  Profile | Blog | P.M. 
好東西。。。做個記號~~
Top
 




All times are GMT++8, the time now is 2024-3-29 23:21

    本论坛支付平台由支付宝提供
携手打造安全诚信的交易社区 Powered by Discuz! 5.0.0  © 2001-2006 Comsenz Inc.
Processed in 0.009411 second(s), 7 queries , Gzip enabled

Clear Cookies - Contact Us - CnPack Website - Archiver - WAP